
Reads and writes PKCS#12 files (.pfx, .p12) in pure Elixir: the private
key, its certificate and the rest of the chain, ready for :ssl and
:public_key.
	No NIF and no openssl binary. Everything runs on top of :crypto and
:public_key, which come with OTP.
	Old and new files. The PBES2/AES files of OpenSSL 3, Java and other
recent tools, and the "legacy" RC2 + 3DES files that many tools still
write. RC2 is built in, so legacy files open even where OpenSSL 3 has no
"legacy" provider.
	Writes them too. AES-256 and SHA-256 by default, the legacy format for
old importers, PBMAC1 on request. The test suite checks that OpenSSL,
LibreSSL, Python and Java read what it writes.
	Safe with untrusted input. Bounded parsing, limits on the key
derivation work, the MAC checked before anything is decrypted, and no key
or password in inspect/1 or in error messages.

Status: v0.1. The API is small and expected to stay, but may still
change before 1.0.

Installation
def deps do
  [{:pkcs12, "~> 0.1"}]
end
Elixir 1.16 or later, OTP 26 or later. No other dependencies.
Usage
{:ok, p12} = PKCS12.decode(File.read!("me.pfx"), "password")

p12.private_key      # PrivateKeyInfo (PKCS#8), in DER
p12.certificate      # the certificate of that key, in DER
p12.ca_certificates  # the other certificates, in DER, in file order
p12.info             # the algorithms the file uses
The time goes to the key derivation that the file asks for, from under a
millisecond to tens of milliseconds (Performance), and it is
paid again on every call: decode a file once, for example at startup, and
keep the result. For files from untrusted sources, see
the limits.
Errors come as {:error, %PKCS12.Error{reason: reason}}, and decode!/3
raises them:
case PKCS12.decode(bin, password) do
  {:ok, p12} -> p12
  {:error, %PKCS12.Error{reason: :invalid_password}} -> ...
  {:error, %PKCS12.Error{reason: :malformed}} -> ...
  {:error, error} -> raise error
end
With :ssl
:ssl.connect(~c"example.com", 443,
  certs_keys: [%{cert: [p12.certificate | p12.ca_certificates],
                 key: {:PrivateKeyInfo, p12.private_key}}],
  verify: :verify_peer,
  cacerts: :public_key.cacerts_get()
)
The same certs_keys works in :ssl.listen/2, and in the TLS options of
HTTP clients built on :ssl, such as Mint, Finch and Req.
With :public_key
key = :public_key.der_decode(:PrivateKeyInfo, p12.private_key)
signature = :public_key.sign(message, :sha256, key)

# PEM, for tools that want it
pem = :public_key.pem_encode([{:PrivateKeyInfo, p12.private_key, :not_encrypted}])
Files from untrusted sources
A PKCS#12 file sets its own iteration counts, so a hostile file can ask for a
lot of CPU. The defaults accept every common file and cap the work at about a
second. For uploads, bound the size of the file, lower the limits and put a
timeout around the call:
PKCS12.decode(bin, password, max_iterations: 200_000, max_total_iterations: 600_000)
p12.info tells what the file uses, so an application can refuse weak
algorithms:
weak? = Enum.any?(p12.info.encryption, &(&1.cipher in [:rc2_40_cbc, :rc4_40, :rc4_128]))
See SECURITY.md for the threat model.
Writing
PKCS12.encode/3 takes the same fields that decode/3 returns, so PEM files
become a .pfx for the systems and tools that import one:
[key] = :public_key.pem_decode(File.read!("key.pem"))
[cert | chain] = for {:Certificate, der, _} <- :public_key.pem_decode(File.read!("chain.pem")), do: der

{:ok, pfx} =
  PKCS12.encode(
    %{private_key: :public_key.pem_entry_decode(key), certificate: cert, ca_certificates: chain},
    "password",
    friendly_name: "My key"
  )
The key can be a PrivateKeyInfo in DER or a key record of :public_key. A
file in an old format can be read and written again in the modern one:
pfx |> PKCS12.decode!(password) |> PKCS12.encode!(password)
For importers that know nothing newer, profile: :legacy writes the format
of OpenSSL 1.x. The options set each algorithm and the iteration count on
their own; see PKCS12.encode/3.
What it reads
		
	Encryption	PBES2 (PBKDF2 with HMAC-SHA-1/224/256/384/512) with AES-128/192/256-CBC, 3DES or DES; the PKCS#12 ciphers: 3DES, 2-key 3DES, RC2-40, RC2-128, and RC4-40/128 when :crypto has RC4
	Integrity	the classic MAC (HMAC-SHA-1/224/256/384/512) and PBMAC1 (RFC 9879); files without a MAC are accepted, and info.mac is nil
	Content	keys (encrypted or not), X.509 certificates, nested SafeContents; other bags (secrets, CRLs) are passed on in p12.bags
	Encoding	DER and BER (indefinite lengths, segmented strings), which some tools write
	Passwords	UTF-8, as RFC 7292 says, and the forms some tools use instead (bytes as characters for non-ASCII passwords, the empty password as no bytes); the MAC decides which one is right

Not supported: files signed with, or encrypted to, a public key instead of a
password (both are very rare).
The test suite reads files written by OpenSSL 3, OpenSSL 1.1.1, LibreSSL,
Python's cryptography and Java's keytool, in their default and legacy
modes, and the test vectors of RFC 9879. CI runs it on OTP 26 to 29, and on
an OpenSSL 3 without the legacy provider.
What it writes
		Key	Certificates	MAC	Iterations
	:modern (default)	PBES2 AES-256-CBC, PBKDF2-HMAC-SHA-256	the same	HMAC-SHA-256	100,000
	:legacy	pbeWithSHAAnd3-KeyTripleDES-CBC	pbeWithSHAAnd40BitRC2-CBC	HMAC-SHA-1	2,048

The modern profile is the format that OpenSSL 3 and Java write by default,
with a higher iteration count than either: the count is what slows down
guessing the password of a stolen file. Options choose AES-128/192, 3DES or
no encryption for each part, any of the MACs above, PBMAC1 or no MAC, the
iteration count, the friendlyName and the localKeyId. The output is DER,
with random salts and IVs.
The test suite has OpenSSL 3 and 1.1.1, LibreSSL, Python's cryptography and
Java's keytool read the files it writes, with each profile and the main
options. What they do not read:
	PBMAC1: OpenSSL before 3.4, LibreSSL and Java 23.
	A key that is not encrypted: Java skips it. Certificates without a key:
Java skips them too, unless they carry an attribute of its own, which the
library does not write.
	Non-ASCII passwords: LibreSSL encodes them byte by byte, so it does not
open files from other tools that use one.
	No MAC: OpenSSL 1.1.1 and LibreSSL open such files only with -nomacver.

Performance
The time is almost all key derivation, so it follows the iteration counts in
the file. On an Apple M-series laptop, OTP 27 with OpenSSL 3.6
(mix run bench/decode.exs and bench/encode.exs).
Reading:
	File	Time
	OpenSSL 3 default (PBES2 AES-256, 2,048 iterations)	0.9 ms
	OpenSSL legacy (RC2-40 + 3DES, 2,048)	2.7 ms
	Java default (PBES2 AES-256, 10,000)	4.1 ms
	Java legacy (MAC 100,000, 50,000)	60 ms
	Wrong password (2,048)	0.35 ms

Writing a key, its certificate and a CA certificate:
	Options	Time
	Default (modern, 100,000 iterations)	39 ms
	Modern with 2,048 iterations, as OpenSSL 3	0.9 ms
	Modern with PBMAC1 (100,000)	35 ms
	Legacy (2,048)	2.6 ms

Reading a file of the default profile takes about as long as writing it.
PBKDF2 runs inside OpenSSL on a dirty scheduler. The PKCS#12 key derivation,
of the legacy ciphers and of the classic MAC, is an Elixir loop over
:crypto.hash/2, which the BEAM preempts like any other code.
Development
mix test
mix precommit   # format, warnings, Credo and tests, before a commit
mix dialyzer
The files in test/fixtures are made by the project, with
test/support/gen_fixtures.sh (OpenSSL 3 and 1.1.1, LibreSSL, Python and a
JDK) and test/support/extract_rfc9879.exs (the RFC 9879 vectors). They are
committed because CI does not have every generator.
The interop tests (mix test --only interop) run the readers they find on
the system and skip the others, as well as a Python cryptography older
than 36; test/support/interop.ex lists the variables that point to them. CI runs them with OpenSSL 3, Python and a JDK.
References
	RFC 7292, PKCS #12 v1.1
	RFC 8018, PKCS #5 v2.1 (PBES2, PBKDF2)
	RFC 9879, PBMAC1 in PKCS #12
	RFC 2268, RC2
	RFC 5958, Asymmetric Key Packages (PKCS #8)

License
Apache-2.0: see the LICENSE and NOTICE files.


  

    Security

Reporting a vulnerability
Please do not open a public issue. Use GitHub's
private vulnerability reporting
on this repository ("Security" tab, "Report a vulnerability"). You should get
an answer within a week. Fixes are released for the latest minor version.
Threat model
The library is meant to read files from anyone: a certificate uploaded by a
user, a file from a partner, a key store found on disk. It assumes the file
may be hostile and the password may be wrong. When it writes, the input comes
from the application and is trusted; the section on writing below covers
what the written file protects.
Malformed input
	PKCS12.decode/3 returns {:error, %PKCS12.Error{}} for any input it cannot
read. It does not raise on malformed input; the test suite feeds it damaged
and random files to check that.
	The parser limits nesting (32 levels of ASN.1, 4 levels of nested
SafeContents) and length fields (4 bytes), and checks every length against
the input before it reads.
	Nothing from the file becomes an atom. Unknown algorithms and bag types are
reported by their OID, as a string.
	The memory used is a small multiple of the input size. Bound the size of
the files you accept; the library does not.

CPU
A PKCS#12 file sets its own iteration counts. Without limits, one small file
could ask for minutes of CPU. Two options cap the work:
	:max_iterations (default 1,000,000) is checked for every key derivation
while the file is parsed, before any of them runs.
	:max_total_iterations (default 4,000,000) caps the work of all
derivations together, counted in iterations of the hash: the MAC checks,
one per form of the password tried, and every decryption. A file with
many encrypted parts, or a wrong password tried in several forms, stops
at this limit.

At the defaults the worst case is about a second of one core. The work runs
in the calling process: PBKDF2 inside OpenSSL on a dirty scheduler, the
PKCS#12 key derivation as an Elixir loop that the BEAM preempts. For files
from untrusted sources, lower both limits and put a timeout around the call
(for example, with Task.async/1 and Task.yield/2).
Integrity and the password
	When the file has a MAC, it is checked first, in constant time
(:crypto.hash_equals/2), and nothing is decrypted before it matches. A
wrong password gives :invalid_password after the MAC check alone.
	Some tools encode the password in other ways than RFC 7292 says. The
library tries those forms (at most two for any password), and the MAC
decides which is right. Each try counts towards :max_total_iterations.
	A file without a MAC has no integrity protection: anyone can change its
unencrypted parts, or replace a certificate. info.mac is nil for such
files; refuse them if you need integrity. Without a MAC, a wrong password
is detected by the padding and the structure of what it decrypts.
	verify_mac: false reads a file without checking its MAC. Use it only to
recover a file you trust.

Weak algorithms
Files in the wild still use RC2-40 and RC4-40 for certificates, 3DES and
SHA-1 for keys and MACs, and low iteration counts. The library reads them,
because refusing would make it useless for many real files. They protect the
file at rest poorly. p12.info reports the algorithms and iteration counts
of each file, so that an application can warn about them or refuse them.
The library implements RC2 and the PKCS#12 key derivation itself, on top of
the SHA-1 of :crypto. They therefore work even where the OpenSSL that OTP
uses refuses legacy algorithms, such as under a FIPS policy. If your policy
forbids reading such files, check p12.info.
Secrets in memory
	inspect/1 of PKCS12 and PKCS12.Bag leaves the private key out, and no
error, exception message or argument check includes the password or key
material.
	The decrypted key is a binary like any other. The BEAM copies binaries
and frees them when the garbage collector decides; there is no way to wipe
them. Keep the key in as few processes as possible, and do not log the
result of PKCS12.decode/3 with tools that bypass inspect/1.
	The returned key and certificates are binaries of their own, not
references into the input or the decrypted buffers.

Side channels
The MAC comparison is constant-time. RC2 and the PKCS#12 key derivation are
written in Elixir and are not hardened against timing or cache attacks. In
the files that use RC2, it protects the certificates, which are public. The
library is meant for reading a file once, such as at startup or after an
upload, not for an oracle that answers many queries with the same key.
What the library does not check
It does not validate certificates: not the chain, the dates, the key usage
or revocation. p12.certificate is the certificate that belongs to the key
by localKeyId or by public key, and p12.ca_certificates is everything
else, in file order. Validate them as your application requires, for
example with :public_key.pkix_path_validation/3.
Writing
	The salts (16 bytes) and the IVs come from :crypto.strong_rand_bytes/1,
the random generator of OpenSSL.
	The password is all that protects a written file. Anyone who gets the file
can try passwords offline, as fast as the key derivation allows. Every
derivation in a file uses the same iteration count, because the cheapest
one would set the pace. The default is 100,000; use a long random password
for files that leave your systems, and a higher count for files that live
long.
	The :legacy profile is weak. Its key derivation is SHA-1 with 2,048
iterations, so guessing is cheap, and the 40-bit key of RC2-40 can be found
without the password, which exposes the certificates (public anyway). Use
it only for importers that need it, and keep such files short-lived.
	key_encryption: :none leaves the key readable by anyone with the file,
and mac: :none leaves the file without integrity protection. They are
meant for trust stores and for files protected by other means.
	The library checks the shape of the key and of the certificates it writes,
not that the certificate belongs to the key, nor that it is valid.
	As when reading, the key and the password are binaries in the memory of
the calling process, which the BEAM cannot wipe.



  

    Changelog

All notable changes to this project are documented here. The format follows
Keep a Changelog, and the project uses
Semantic Versioning.
0.1.1 - 2026-10-23
Fixed
	The interop tests skip a Python cryptography older than 36, which has no
load_pkcs12, instead of failing.

Documentation
	decode/3: nil is the same as the empty password, and what that means
for a password read from an environment variable that is not set.
	decode/3 and the README: the key derivation is paid on every call, so a
file is best decoded once and the result kept.

0.1.0 - 2026-10-23
Added
	PKCS12.decode/3 and PKCS12.decode!/3: read a PKCS#12 file and return the
private key, its certificate, the other certificates, every bag with its
attributes, and the algorithms the file uses.
	Encryption: PBES2 with AES-CBC, 3DES or DES, and the PKCS#12 ciphers (3DES,
2-key 3DES, RC2-40, RC2-128, RC4). RC2 is implemented by the library.
	Integrity: the classic MAC with SHA-1 to SHA-512, and PBMAC1 (RFC 9879).
	BER input, and the password encodings of tools that differ from RFC 7292.
	Limits on the key derivation work (:max_iterations,
:max_total_iterations) and verify_mac: false.
	PKCS12.encode/3 and PKCS12.encode!/3: write a PKCS#12 file from a key
(PrivateKeyInfo in DER, or a key record of :public_key), its certificate
and other certificates. The :modern profile (default) uses AES-256-CBC
with PBKDF2-HMAC-SHA-256 and a SHA-256 MAC, with 100,000 iterations; the
:legacy profile, 3DES and RC2-40 with a SHA-1 MAC. Options choose each
algorithm, PBMAC1, the iteration count, friendlyName and localKeyId.

Reads and writes PKCS#12 files (.pfx, .p12): the private key, its
certificate and the rest of the chain.
{:ok, p12} = PKCS12.decode(File.read!("me.pfx"), "password")

p12.private_key      # PrivateKeyInfo (PKCS#8), in DER
p12.certificate      # the certificate of that key, in DER
p12.ca_certificates  # the other certificates, in DER, in file order

{:ok, pfx} = PKCS12.encode(p12, "new password")
Everything is done in Elixir on top of :crypto and :public_key, with no
NIF of its own and no call to the openssl binary. RC2, which the legacy
files use for their certificates, is implemented by the library, because
OpenSSL 3 only has it in its "legacy" provider, often missing.
Using the result
The key and the certificates are DER binaries, the form that the rest of
OTP takes:
# TLS client authentication (mTLS)
:ssl.connect(host, 443,
  certs_keys: [%{cert: [p12.certificate | p12.ca_certificates],
                 key: {:PrivateKeyInfo, p12.private_key}}],
  verify: :verify_peer,
  cacerts: :public_key.cacerts_get()
)

# Signing
key = :public_key.der_decode(:PrivateKeyInfo, p12.private_key)
signature = :public_key.sign(message, :sha256, key)

# PEM files, for tools that want them
pem = :public_key.pem_encode([{:PrivateKeyInfo, p12.private_key, :not_encrypted}])
Writing
encode/3 takes the same fields, so PEM files become a .pfx for the
systems and tools that import one:
[key] = :public_key.pem_decode(File.read!("key.pem"))
[cert | chain] = for {:Certificate, der, _} <- :public_key.pem_decode(File.read!("chain.pem")), do: der

{:ok, pfx} =
  PKCS12.encode(
    %{private_key: :public_key.pem_entry_decode(key), certificate: cert, ca_certificates: chain},
    "password",
    friendly_name: "My key"
  )
A file in an old format can be read and written again in the modern one:
pfx |> PKCS12.decode!(password) |> PKCS12.encode!(password)
Algorithms
Reading, encryption:
	PBES2 (PBKDF2 with HMAC-SHA-1/224/256/384/512) with AES-128/192/256-CBC,
3DES-CBC or DES-CBC, the default of OpenSSL 3, Java and other recent
tools;
	pbeWithSHAAnd3-KeyTripleDES-CBC and pbeWithSHAAnd40BitRC2-CBC, the
"legacy" combination of OpenSSL 1.x and of many older tools, still
common;
	the other PKCS#12 ciphers: 2-key 3DES, RC2-128, and RC4-40/128 when
:crypto has RC4.

Reading, integrity: the classic MAC with SHA-1/224/256/384/512, and PBMAC1
(RFC 9879). Files without a MAC are accepted; :info tells.
Writing: PBES2 with AES and PBKDF2-HMAC-SHA-256 by default, the legacy
combination when asked, and any of the MACs above. See encode/3.
Not supported: files signed with, or encrypted to, a public key instead of
a password (both are very rare).
Passwords
The password is a UTF-8 binary, or nil, which is the same as "". Some
generators encode passwords in other ways: with each byte as a character
(non-ASCII passwords in older OpenSSL versions and LibreSSL), or the empty
password as no bytes at all. When reading, the library tries those forms
too, and the MAC decides which is right; :info tells which one matched.
When writing, it uses the standard forms only.

        A cipher that encode/3 writes.

        A hash algorithm, named as in :crypto.



    


    
      
        info()

      


        What the file uses.

        What encode/3 writes: a t/0, or a map with any of its first three
keys. See encode/3.

        A decoded PKCS#12 file.

        decode(pfx, password, opts \\ [])

      


        Decodes a PKCS#12 file.



    


    
      
        decode!(pfx, password, opts \\ [])

      


        Like decode/3, but returns the result or raises PKCS12.Error.



    


    
      
        encode(p12, password, opts \\ [])

      


        Encodes a PKCS#12 file, in DER.



    


    
      
        encode!(p12, password, opts \\ [])

      


        Like encode/3, but returns the file or raises PKCS12.Error.

          @type cipher() ::
  :aes_256_cbc | :aes_192_cbc | :aes_128_cbc | :des_ede3_cbc | :rc2_40_cbc


      


A cipher that encode/3 writes.

          @type decode_option() ::
  {:max_iterations, pos_integer()}
  | {:max_total_iterations, pos_integer()}
  | {:verify_mac, boolean()}

          @type encode_option() ::
  {:profile, :modern | :legacy}
  | {:key_encryption, cipher() | :none}
  | {:certificate_encryption, cipher() | :none}
  | {:mac, hash() | :pbmac1 | :none}
  | {:iterations, pos_integer()}
  | {:friendly_name, String.t()}
  | {:local_key_id, binary()}

          @type hash() :: :sha | :sha224 | :sha256 | :sha384 | :sha512


      


A hash algorithm, named as in :crypto.

          @type info() :: %{
  mac:
    nil
    | %{
        scheme: :hmac | :pbmac1,
        digest: hash(),
        prf: hash() | nil,
        iterations: pos_integer(),
        verified: boolean()
      },
  encryption: [
    %{
      scheme: :pbes2 | :pkcs12_pbe,
      cipher: atom(),
      digest: hash(),
      iterations: pos_integer()
    }
  ],
  password_encoding: :unicode | :latin1 | :null | nil
}


      


What the file uses.
	:mac - nil if the file has no MAC, otherwise a map with :scheme
(:hmac, the classic MAC, or :pbmac1), :digest (the HMAC hash),
:prf (the PBKDF2 hash of PBMAC1, nil for :hmac), :iterations
and :verified (false with verify_mac: false).
	:encryption - one map per distinct algorithm, with :scheme
(:pbes2 or :pkcs12_pbe), :cipher (such as :aes_256_cbc,
:des_ede3_cbc or :rc2_40_cbc), :digest (the hash of the key
derivation) and :iterations: first those of the encrypted parts of
the file, then those of the encrypted keys. Empty if nothing is
encrypted.
	:password_encoding - which form of the password matched: :unicode
(the standard one), :latin1 or :null. nil if the password was
not needed.

More keys may be added in later versions.

          @type input() ::
  t()
  | %{
      optional(:private_key) => binary() | tuple() | nil,
      optional(:certificate) => binary() | nil,
      optional(:ca_certificates) => [binary()] | nil
    }


      


What encode/3 writes: a t/0, or a map with any of its first three
keys. See encode/3.

          @type t() :: %PKCS12{
  bags: [PKCS12.Bag.t()],
  ca_certificates: [binary()],
  certificate: binary() | nil,
  info: info(),
  private_key: binary() | nil
}


      


A decoded PKCS#12 file.
	:private_key - the first private key of the file, as a
PrivateKeyInfo (PKCS#8) in DER, or nil if the file has none.
inspect/1 leaves it out.
	:certificate - the certificate of that key, in DER: the one with the
same localKeyId, or else the one with the same public key. nil if
there is no key, or no certificate matches.
	:ca_certificates - every other certificate, in DER, in file order.
In files with a key, that is usually the chain; the library does not
reorder or validate it.
	:bags - every bag of the file, as PKCS12.Bag.t/0, in file order,
with their attributes. Files with more than one key list them all
here.
	:info - what the file uses, to warn about or refuse weak algorithms
(see info/0).

          @spec decode(binary(), String.t() | nil, [decode_option()]) ::
  {:ok, t()} | {:error, PKCS12.Error.t()}


      


Decodes a PKCS#12 file.
password is a binary (UTF-8 text, as typed by the user) or nil, which
is the same as "". A password read with System.get_env/1 is nil when
the variable is not set, and a file with a password then fails with
:invalid_password; System.fetch_env!/1 raises first, with the name of
the variable.
Options
	:max_iterations - the largest iteration count accepted for any one
key derivation. Default: 1000000. Common tools
write from 2,048 to 100,000 (the MAC of the Java legacy format); a
much larger count in a file from an untrusted source is a way to make
the server spend CPU.
	:max_total_iterations - the limit for the work of all derivations
together: the MAC checks (one per form of the password tried) and
every decryption. Each counts its iteration count times the output
blocks of the hash it needs, so a legacy 3DES decryption of 2,048
iterations counts 6,144: two blocks for the key and one for the IV.
Default: 4 times :max_iterations.
	:verify_mac - whether to check the MAC. Default: true. With
false, a file with a damaged MAC can still be read, but nothing tells
whether it was changed; use it only to recover a file you trust.

The work is CPU-bound: a few milliseconds for common files, up to about a
second at the default limits, paid again on every call. Decode a file
once, for example at startup, and keep the result. The work runs in the
calling process, which the BEAM preempts as usual. To read files from untrusted sources, bound their
size, lower the limits and consider a timeout around the call.
Errors
Returns {:error, %PKCS12.Error{}}; see PKCS12.Error for the reasons.
A wrong password gives :invalid_password.

          @spec decode!(binary(), String.t() | nil, [decode_option()]) :: t()


      


Like decode/3, but returns the result or raises PKCS12.Error.

  



    

  
    
      
    
    
      encode(p12, password, opts \\ [])



        
          
        

    

  


  

      

          @spec encode(input(), String.t() | nil, [encode_option()]) ::
  {:ok, binary()} | {:error, PKCS12.Error.t()}


      


Encodes a PKCS#12 file, in DER.
p12 is a t/0, such as one that decode/3 returns, or a map with
some of the same keys:
	:private_key - a PrivateKeyInfo (PKCS#8) in DER, or a key record of
:public_key, such as {:RSAPrivateKey, ...} or {:ECPrivateKey, ...}.
	:certificate - the certificate of that key, in DER.
	:ca_certificates - other certificates, in DER, usually the rest of
the chain. They are written in this order, after :certificate.

Any of them can be missing: a file of certificates alone, for example, is
a trust store. Other keys, such as :bags and :info, are ignored, so
only the first key of a decoded file and its certificates are written
again. The library checks the shape of the key and of the certificates,
not that the certificate belongs to the key.
password is a UTF-8 binary, or nil, which is the same as "".
The salts and IVs come from :crypto.strong_rand_bytes/1, so no two
results are the same.
Options
	:profile - the values of the options below when they are not given:	:modern (default) - AES-256-CBC with PBKDF2-HMAC-SHA-256 for the
key and for the certificates, and a SHA-256 MAC, all with 100,000
iterations. It is the format that OpenSSL 3 and Java write by
default, with a higher count than either.
	:legacy - pbeWithSHAAnd3-KeyTripleDES-CBC for the key,
pbeWithSHAAnd40BitRC2-CBC for the certificates and a SHA-1 MAC, all
with 2,048 iterations: the format of OpenSSL 1.x, for importers
that know nothing newer. It is weak; see the
security notes.


	:key_encryption - :aes_256_cbc, :aes_192_cbc or :aes_128_cbc
(PBES2 with PBKDF2-HMAC-SHA-256), :des_ede3_cbc
(pbeWithSHAAnd3-KeyTripleDES-CBC), or :none.
	:certificate_encryption - the same choices, and :rc2_40_cbc
(pbeWithSHAAnd40BitRC2-CBC). With :none, anyone can read the
certificates, as they could anyway from the certificates themselves.
	:mac - :sha256, :sha384, :sha512, :sha224 or :sha (the
classic MAC with that hash), :pbmac1 (RFC 9879, with
PBKDF2-HMAC-SHA-256 and HMAC-SHA-256, which OpenSSL reads from 3.4 on),
or :none.
	:iterations - the iteration count of every key derivation. A
password is as hard to guess as the cheapest derivation that checks
it, so they all take the same. The cost grows with the count when
writing and when reading; decode/3 reads up to 1,000,000 by
default, and other readers have limits of their own.
	:friendly_name - a name for the key and its certificate, which
importers show; Java uses it as the alias.
	:local_key_id - the localKeyId of the key and its certificate, which
readers use to pair them. Default: the SHA-1 hash of the certificate,
when there are both.

An option given as nil takes the value of the profile.
Errors
Returns {:error, %PKCS12.Error{}} with {:invalid_input, field} when a
field of p12 is not what it should be, or {:not_available, cipher}
when :crypto refuses a cipher, as a FIPS provider may do with
:des_ede3_cbc. Raises ArgumentError for invalid options, or for a
password that is not UTF-8.

  



    

  
    
      
    
    
      encode!(p12, password, opts \\ [])



        
          
        

    

  


  

      

          @spec encode!(input(), String.t() | nil, [encode_option()]) :: binary()


      


Like encode/3, but returns the file or raises PKCS12.Error.

  


        

      


  

    
PKCS12.Bag 
    



      
One SafeBag of a PKCS#12 file: a private key, a certificate or something
else, with its attributes.
PKCS12.decode/3 lists every bag of the file in PKCS12.t/0, in file
order. Most programs only need the :private_key, :certificate and
:ca_certificates fields there; the bags are for files with more than one
key, for the friendly names and for attributes the library does not
interpret.
Fields:
	:type - :private_key, :certificate or :other.
	:value - for :private_key, the PrivateKeyInfo (PKCS#8) in DER,
already decrypted; for :certificate, the X.509 certificate in DER;
for :other, the DER of the bag value as it is in the file.
	:oid - the bag type (bagId), in dotted form.
	:friendly_name - the friendlyName attribute, or nil.
	:local_key_id - the localKeyId attribute, or nil. A key and its
certificate usually share it.
	:attributes - the other attributes, as {oid, values} with each
value in DER, in file order.

inspect/1 leaves :value out, so that a private key does not end up in
a log by accident.

          @type t() :: %PKCS12.Bag{
  attributes: [{String.t(), [binary()]}],
  friendly_name: String.t() | nil,
  local_key_id: binary() | nil,
  oid: String.t(),
  type: type(),
  value: binary()
}

          @type type() :: :private_key | :certificate | :other


      



  


        

      


  

    
PKCS12.Error exception
    



      
Why a PKCS#12 file could not be read or written.
PKCS12.decode/3 and PKCS12.encode/3 return it as
{:error, %PKCS12.Error{}}, and PKCS12.decode!/3 and PKCS12.encode!/3
raise it. Match on :reason:
	:malformed - not a valid PKCS#12 structure.
	:invalid_password - the MAC does not match, or, in a file without a
MAC, the content does not decrypt.
	{:unsupported_version, version} - the PFX version is not 3.
	{:unsupported_algorithm, oid} - an algorithm the library does not
implement, with its OID in dotted form.
	{:unsupported, :public_key_integrity | :public_key_privacy} - the
file is signed with, or encrypted to, a public key instead of a
password. Such files are very rare.

	{:not_available, algorithm} - the library knows the algorithm, but
the :crypto application of this system (its OpenSSL) refuses it. For
example, RC4 when the OpenSSL "legacy" provider is missing, or
parameters that a FIPS provider rejects.
	{:too_many_iterations, count} - one key derivation asks for more
iterations than the :max_iterations option allows.
	{:too_many_total_iterations, count} - the work of all derivations
together goes beyond the :max_total_iterations option; count is
the work done or due when the limit was reached.
	{:unsupported_mac_key_size, bytes} - a PBMAC1 key size outside
20..64 bytes.
	{:invalid_input, field} - when writing, field (:private_key,
:certificate or :ca_certificates) is not a key or certificates in
a form that PKCS12.encode/3 takes.

The error never carries the password or any key material.

          @type reason() ::
  :malformed
  | :invalid_password
  | {:unsupported_version, non_neg_integer()}
  | {:unsupported_algorithm, String.t()}
  | {:unsupported, :public_key_integrity | :public_key_privacy}
  | {:not_available, atom()}
  | {:too_many_iterations, pos_integer()}
  | {:too_many_total_iterations, pos_integer()}
  | {:unsupported_mac_key_size, non_neg_integer()}
  | {:invalid_input, :private_key | :certificate | :ca_certificates}

          @type t() :: %PKCS12.Error{__exception__: true, reason: reason()}

